pygmalion: use pure zsh instead of perl (#9210)

My system doesn't have `perl` in $PATH, so using this theme clutters the
shell output quite a bit.

Turns out, the same thing can be accomplished in pure zsh (with
extendedglob).

Co-Authored-By: Marc Cornellà <marc.cornella@live.com>

plugins/vagrant-prompt/vagrant-prompt.plugin.zsh

@@ -16,22 +16,17 @@
 # ZSH_THEME_VAGRANT_PROMPT_NOT_CREATED="%{$fg_no_bold[white]%}○"
 
 function vagrant_prompt_info() {
-  test -d .vagrant && test -f Vagrantfile
+  local vm_states vm_state
-  if [[ "$?" == "0" ]]; then
+  if [[ -d .vagrant && -f Vagrantfile ]]; then
-    statuses=$(vagrant status 2> /dev/null | grep -P "\w+\s+[\w\s]+\s\(\w+\)")
+    vm_states=(${(f)"$(vagrant status 2> /dev/null | sed -nE 's/^.*(saved|poweroff|running|not created) \([[:alnum:]_]+\)$/\1/p')"})
-    statuses=("${(f)statuses}")
     printf '%s' $ZSH_THEME_VAGRANT_PROMPT_PREFIX
-    for vm_details in $statuses; do
+    for vm_state in $vm_states; do
-      vm_state=$(echo $vm_details | grep -o -E "saved|poweroff|not created|running")
+      case "$vm_state" in
-      if [[ "$vm_state" == "running" ]]; then
+        saved) printf '%s' $ZSH_THEME_VAGRANT_PROMPT_SUSPENDED ;;
-        printf '%s' $ZSH_THEME_VAGRANT_PROMPT_RUNNING
+        running) printf '%s' $ZSH_THEME_VAGRANT_PROMPT_RUNNING ;;
-      elif [[ "$vm_state" == "saved" ]]; then
+        poweroff) printf '%s' $ZSH_THEME_VAGRANT_PROMPT_POWEROFF ;;
-        printf '%s' $ZSH_THEME_VAGRANT_PROMPT_SUSPENDED
+        "not created") printf '%s' $ZSH_THEME_VAGRANT_PROMPT_NOT_CREATED ;;
-      elif [[ "$vm_state" == "not created" ]]; then
+      esac
-        printf '%s' $ZSH_THEME_VAGRANT_PROMPT_NOT_CREATED
-      elif [[ "$vm_state" == "poweroff" ]]; then
-        printf '%s' $ZSH_THEME_VAGRANT_PROMPT_POWEROFF
-      fi
     done
     printf '%s' $ZSH_THEME_VAGRANT_PROMPT_SUFFIX
   fi

themes/pygmalion-virtualenv.zsh-theme

@@ -17,6 +17,8 @@ function _virtualenv_prompt_info {
 }
 
 prompt_setup_pygmalion(){
+  setopt localoptions extendedglob
+
   ZSH_THEME_GIT_PROMPT_PREFIX="%{$reset_color%}%{$fg[green]%}"
   ZSH_THEME_GIT_PROMPT_SUFFIX="%{$reset_color%} "
   ZSH_THEME_GIT_PROMPT_DIRTY="%{$fg[yellow]%}⚡%{$reset_color%}"
@@ -25,16 +27,18 @@ prompt_setup_pygmalion(){
   base_prompt='$(_virtualenv_prompt_info)%{$fg[magenta]%}%n%{$reset_color%}%{$fg[cyan]%}@%{$reset_color%}%{$fg[yellow]%}%m%{$reset_color%}%{$fg[red]%}:%{$reset_color%}%{$fg[cyan]%}%0~%{$reset_color%}%{$fg[red]%}|%{$reset_color%}'
   post_prompt='%{$fg[cyan]%}⇒%{$reset_color%}  '
 
-  base_prompt_nocolor=$(echo "$base_prompt" | perl -pe "s/%\{[^}]+\}//g")
+  base_prompt_nocolor=${base_prompt//\%\{[^\}]##\}}
-  post_prompt_nocolor=$(echo "$post_prompt" | perl -pe "s/%\{[^}]+\}//g")
+  post_prompt_nocolor=${post_prompt//\%\{[^\}]##\}}
 
   autoload -U add-zsh-hook
   add-zsh-hook precmd prompt_pygmalion_precmd
 }
 
 prompt_pygmalion_precmd(){
+  setopt localoptions extendedglob
+
   local gitinfo=$(git_prompt_info)
-  local gitinfo_nocolor=$(echo "$gitinfo" | perl -pe "s/%\{[^}]+\}//g")
+  local gitinfo_nocolor=${gitinfo//\%\{[^\}]##\}}
   local exp_nocolor="$(print -P \"$base_prompt_nocolor$gitinfo_nocolor$post_prompt_nocolor\")"
   local prompt_length=${#exp_nocolor}
 

themes/pygmalion.zsh-theme

@@ -1,6 +1,8 @@
 # Yay! High voltage and arrows!
 
 prompt_setup_pygmalion(){
+  setopt localoptions extendedglob
+
   ZSH_THEME_GIT_PROMPT_PREFIX="%{$reset_color%}%{$fg[green]%}"
   ZSH_THEME_GIT_PROMPT_SUFFIX="%{$reset_color%} "
   ZSH_THEME_GIT_PROMPT_DIRTY="%{$fg[yellow]%}⚡%{$reset_color%}"
@@ -9,16 +11,18 @@ prompt_setup_pygmalion(){
   base_prompt='%{$fg[magenta]%}%n%{$reset_color%}%{$fg[cyan]%}@%{$reset_color%}%{$fg[yellow]%}%m%{$reset_color%}%{$fg[red]%}:%{$reset_color%}%{$fg[cyan]%}%0~%{$reset_color%}%{$fg[red]%}|%{$reset_color%}'
   post_prompt='%{$fg[cyan]%}⇒%{$reset_color%}  '
 
-  base_prompt_nocolor=$(echo "$base_prompt" | perl -pe "s/%\{[^}]+\}//g")
+  base_prompt_nocolor=${base_prompt//\%\{[^\}]##\}}
-  post_prompt_nocolor=$(echo "$post_prompt" | perl -pe "s/%\{[^}]+\}//g")
+  post_prompt_nocolor=${post_prompt//\%\{[^\}]##\}}
 
   autoload -U add-zsh-hook
   add-zsh-hook precmd prompt_pygmalion_precmd
 }
 
 prompt_pygmalion_precmd(){
+  setopt localoptions extendedglob
+
   local gitinfo=$(git_prompt_info)
-  local gitinfo_nocolor=$(echo "$gitinfo" | perl -pe "s/%\{[^}]+\}//g")
+  local gitinfo_nocolor=${gitinfo//\%\{[^\}]##\}}
   local exp_nocolor="$(print -P \"$base_prompt_nocolor$gitinfo_nocolor$post_prompt_nocolor\")"
   local prompt_length=${#exp_nocolor}